Making a monster spawn another monster when it dies?

[SamUK]

Yep.

I've started on a new monster, almost done with it. When I thought I was done, bang problem.

I want to make a monster that idle. It just sits on the wall, however you kill it, it spawns a bunch of creatures. I thought it'd be pretty simple.

Code: Select all

 void() pod_die =
{
// regular death
   sound (self, CHAN_VOICE, "infection/death1.wav", 1, ATTN_NORM);   
   Monster_infection (Self.origin);
   CreateFblood (self.origin);
   pod_die1 (self.origin);

However, when the pod dies, the infection monster spawns, but it's like it's not connected to the AI as it just stands there doing nothing. I can still kill it of course, it just doesn't do anything.

Any help?

(Warning, newbie here )

[Team Xlink]

Well do any of the things you called in your code have the AI routine in it? If not you need to add it.

[Dr. Shadowborg]

Is it animating? If not you probably need to do something to initialize it in it's spawn function, probably something like this for example:

Code: Select all

newmonster.think = evile_stand;
newmonster.nextthink = time + 0.1;


[Team Xlink]

Is it animating? If not you probably need to do something to initialize it in it's spawn function, probably something like this for example:

Code: Select all

newmonster.think = evile_stand;
newmonster.nextthink = time + 0.1;


Is it doing damage to the player?

If it is then I think Dr. Shadowborg is right.

Where exactly is your AI routine located?

[Wazat]

Also note that if you're not calling walkmosnter_start (or the corresponding fly/swim functions) you can have other problems, like your monster kill count not matching the maximum.

Make sure you're calling the _start function and that your animations are set up to loop properly (i.e. walk, stand, etc). The animations should also call the appropriate AI functions like ai_stand();

Mind if we take a gander at the Monster_infection function?

-Wazat

[SamUK]

Bare with me.

Sure, Wazat.

Code: Select all

void() monster_infection =
{
   if (deathmatch)
   {
      remove(self);
      return;
   }
   precache_model ("progs/h_infected.mdl");
   precache_model ("progs/infectedflood.mdl");
   precache_model ("GFX/bflood.spr");
   
   precache_sound ("infection/dattack1.wav");
   precache_sound ("infection/ddeath.wav");
   precache_sound ("infection/idle.wav");

   self.solid = SOLID_SLIDEBOX;
   self.movetype = MOVETYPE_STEP;

   setmodel (self, "progs/infectedflood.mdl");

   setsize (self, '-8 -8 -8', '8 8 8');
   self.health = 1;

   self.th_stand = infection_stand1;
   self.th_walk = infection_walk1;
   self.th_run = infection_run1;
   self.th_die = infection_die; // Gibing only
   self.th_melee = infection_atta1;
   self.th_missile = infection_leap1;

   walkmonster_start();
};


No, it's doing nothing but spawn and die. Also, what do you mean by Ai routine, not up to scrtach with my coding jargon.

[frag.machine]

I had a similar problem with my skeleton king monster; it spawns zombies to fight its enemies. I solved the zombies ignoring the skel's enemies with this:

Code: Select all

   // let the spawned monster fight against the parent's enemies
        // (assume self = the parent monster)
   sight_entity = self;
   sight_entity_time = time;


EDIT: spellcheck, removed a bit of useless code and added a better comment

[SamUK]

Hmm, it's getting there. It moves now. Still doesn't attack though.

[Team Xlink]

SamUK may I have your permission to fix it and upload an improved version for us?

[Dr. Shadowborg]

Hmm, what you've got there in monster_infection should only work for monster_infection placed in the map by the mapper. (Just guessing, but are you using Darkplaces or something? Don't worry, it's just that Darkplaces has a habit of allowing things that make stuff that should break normal engines not break, which while good, is also very bad for teaching proper modding techniques. Another problem I see there is that monster_infection isn't set up to take any vectors.)

Anyway, you need to make a separate spawn function for your pod spawned infection monsters that also takes into account the relativity factor. i.e. self in the case of pod_die() is the pod, not the monster_infection, hence when monster_infection is called it doesn't set up the monster_infection's functions, it just modifies your pod entity.

In short, you need to create a copy of monster_infection similiar to the following: (note, I've taken out the precaches and deathmatch removal, they should be defined within monster_pod or whatever)

Code: Select all


void(vector org) monster_pod_infection =
{
   local entity stemp;
   
   newmis = spawn();
   stemp = self;
   self = newmis;
   
   setorigin(self, org);
   self.solid = SOLID_SLIDEBOX;
   self.movetype = MOVETYPE_STEP;

   setmodel (self, "progs/infectedflood.mdl");

   setsize (self, '-8 -8 -8', '8 8 8');
   self.health = 1;

   self.th_stand = infection_stand1;
   self.th_walk = infection_walk1;
   self.th_run = infection_run1;
   self.th_die = infection_die; // Gibing only
   self.th_melee = infection_atta1;
   self.th_missile = infection_leap1;

   walkmonster_start();

   self = stemp;
};


Hope this helps!

[Wazat]

As Doc Shadowborg pointed out, your precache functions etc should be moved into the spawn function of the monster that creates these creatures on death. Precache should only ever happen during the map loading. Darkplaces handles it nicely, but other engines probably won't.

The fact that your monsters aren't performing their own target acquisition worries me though. Perhaps something is missing in the animations that handles the target searching (i.e. ai_stand etc). Can you post the code for the animations?

Actually, it may be that nothing is wrong with the animation code. It could very well be that the fix Dr. Shadowborg posted will fix it. As he said, your spawn function was modifying self instead of a newly spawned entity, so it was setting all this info on the pod. Perhaps something was going awry there. Although modifying the original entity and turning it into the infection shouldn't hurt anything presumably... You just can't spawn multiple infection monsters that way.

If Shadow's fixes don't get your spawnlings searching for the player, let's have a look at the walk, stand, run etc animations.

[SamUK]

Ahh, cheers guys! It's working.



Note: The art is all wip. Something I made real quick to test it out. A decent sprite and texture should make all the difference.

Edit: Also, the muzzleflash has been replaced. I've just got an old build running on darkplaces.

[Wazat]

Hurray! Congrats, man.

[Teiman]

man, I hate these evil fungus